Description: Applesoft: Stopping the Apple IIe cursor from blinking
Header: Applesoft: Stopping the Apple IIe cursor from blinking

 You prefer a solid non-flashing cursor over the flashing "checkerboard" that
 the Apple IIe normally provides? If you have Apple's 80-column Text Card just
 type PR#3, then ESC-4.  The system will have the eighty column cursor (a solid
 non-flashing blank) and will be in 40-column mode.

 If you do not have a Text Card, fear not; just type

      POKE 49162,0: PRINT CHR$(4);"PR#3"

 and you can get the same effect.

 You can use this next sample routine as the startup program on a diskette or
 the startup routine in an Applesoft program.  Line 14 determines whether it is
 on an Apple IIe or an Apple II.  If, by the time Line 16 executes, no Apple
 Text Card is detected in the system, then Line 18 enables the 80-column
 firmware.

 [NOTE:  The firmware is enabled by the monitor during Cold Boot (i.e.,
 power-on startup or OPEN-APPLE-CTRL-RESET) if there is a Text Card
 installed].

 Line 18 activates the firmware now that it is enabled.  The 80-column firmware
 maintains a mode status byte in RAM at location 1275 ($04FB).  Bit 7 of this
 byte determines whether Lowercase Restrict mode is active or not.  Line 28
 guarantees that this bit is set to enable the mode.  Lowercase Restrict mode
 is normally only available in direct mode typing Escape-R and cannot be done
 othEW ise in a program.

 10  TEXT : SPEED= 255
 12  D$ =  CHR$(4): REM CTRL-D
 14  IF  NOT ( PEEK (64435) = 6) GOTO 30: REM NOT APPLE IIE
 16  IF  NOT ( PEEK (49162) < 128) GOTO 20:
     REM TEXT CARD INSTALLED
 18  POKE 49162,0: REM ENABLE 80-COLUMN FIRMWARE
 20  PRINT D$;"PR#3": PRINT : REM ACTIVATE FIRMWARE
 22  PRINT  CHR$(17): REM SWITCH TO 40-COLUMN MODE
 24  MB = 1275: REM 80-COLUMN FIRMWARE MODE BYTE ($04FB)
 26  MS =  PEEK (MB): REM READ CURRENT MODE STATUS
 28  IF (MS < 128) THEN  POKE MB,MS + 128:
    REM SET BIT-7 TO ENABLE LOWER CASE RESTRICT MODE
 30  NORMAL : HOME
 Apple Technical Communications


 Keywords: