PAGE
         SBTL  'DUMP - VGP][   (C) DIGISOLVE LTD 1984'
                          ; PROGRAMMED BY ALAN COAKER 
                          ; DATE 2/APRIL/84
                          ;
KBD      EQU   $C000      ; KEYBOARD INTERFACE
CKBDS    EQU   $C010      ; KEYBOARD STROBE RESET
                          ;
ESCAPE   EQU   $1B
                          ;
JUMP1    EQU   $9D        ; PAGE 0 JUMP TO LPRINT
JUMP2    EQU   JUMP1+1
JUMP3    EQU   JUMP1+2
                          ;
XMASK    EQU   $55        ; BIT MASK FOR COLOUR TEST
DOTS     EQU   $56        ; TEMP STORE TO BUILD PRINTER OUTPUT
TXPAGE   EQU   $57        ; VGP][ PAGE FOR DUMP
                          ;
VBASE    EQU   $A0        ; BASE POINTER TO VGP
VBASE1   EQU   $A2        ; BASE FOR VGP COLOUR
                          ;
IBASE    EQU   $A8        ; BASE POINTER TO PRINTER INTERFACE
IBASE1   EQU   $AA        ; BASE1 FOR EPSON INTERFACE
                          ;
         ORG   $4000      ; PROGRAM ORIGIN
                          ;
START:   LDA   #$4C       ; JUMP OPCODE
         STA   JUMP1
         LDA   #>LPRINT   ; JUMP TO LPRINT LSB
         STA   JUMP2
         LDA   #<LPRINT   ; JUMP TO LPRINT MSB 
         STA   JUMP3
         CLC
         BCC   DUMP       ; SKIP OVER TEMP STORAGE
                          ;
LPRINT:  PHA              ; OUTPUT CHAR TO PRINTER
         LDY   #ITYPEO
         LDA   (JUMP2),Y  ; GET INTERFACE TYPE
         TAY
         DEY              ; GRAPPLER ?
         BEQ   LGRAPP
         DEY
         BEQ   LGPLUS
LEPSON:  LDY   #1
LEPS1:   LDA   (IBASE1),Y
         BMI   LEPS1      ; WAIT FOR NOT BUSY
         PLA              ; GET CHARACTER
         DEY
         STA   (IBASE),Y  ; OUTPUT TO PRINTER
         RTS
                          ;
LGPLUS:  LDY   #1         ; GRAPPLER+
PAPER1:  LDA   (IBASE),Y
         EOR   #2
         AND   #$0E
         BNE   PAPER1
         LDY   #$20
W1:      DEY
         BNE   W1
         INY
         PLA
         STA   (IBASE),Y  ; OUTPUT TO PRINTER
         INY
         STA   (IBASE),Y  ; STROBE ON
         LDY   #4
         STA   (IBASE),Y  ; STROBE OFF
         RTS
                          ;
LGRAPP:  LDY   #1
PAPER2:  LDA   (IBASE),Y
         EOR   #3
         AND   #7
         BNE   PAPER2
         LDY   #$20
W2:      DEY
         BNE   W2
         INY
         PLA
         STA   (IBASE),Y  ; OUTPUT TO PRINTER
         RTS              ; AUTO STROBE ON GRAPPLER
                          ;
PTYPE:   DFB   3          ; 1:MX80 2:MX100 3:RX80 4:RX100 5:MX82 6:FX80 
ISLOT:   DFB   1          ; INTERFACE SLOT NO.
ITYPE:   DFB   2          ; 1:GRAPPLER 2:GRAPPLER+ 3:EPSON
VSLOT:   DFB   4          ; VGP SLOT NO.
FORMAT:  DFB   1          ; 0:USA 1:UK
INTERL:  DFB   1          ; 0:NON 1:INTERLACED
COLOUR:  DFB   1          ; 0:MONO 1:COLOUR
                          ;
PTYPEO   EQU   PTYPE-LPRINT
ISLOTO   EQU   PTYPEO+1
ITYPEO   EQU   PTYPEO+2
VSLOTO   EQU   PTYPEO+3
FORMO    EQU   PTYPEO+4
INTRO    EQU   PTYPEO+5
COLRO    EQU   PTYPEO+6
                          ;
DUMP:    LDY   #VSLOTO    ; SET UP VGP BASE POINTER
         LDA   (JUMP2),Y  ; GET SLOT NO.
         AND   #7
         ORA   #$C0
         STA   VBASE1+1
         ASL   A
         ASL   A
         ASL   A
         ASL   A          ; MULTIPLY SLOT * 16
         ADC   #$80       ; ADD #$80 FOR VGP BASE
         STA   VBASE
         LDY   #ISLOTO    ; SET UP INTERFACE POINTERS 
         LDA   (JUMP2),Y  ; GET SLOT NO.
         AND   #7
         ORA   #$C0
         STA   IBASE1+1
         ASL   A
         ASL   A
         ASL   A
         ASL   A          ; MULTIPLY SLOT * 16
         ADC   #$80       ; ADD #$80 FOR BASE
         STA   IBASE
         LDA   #$C0
         STA   VBASE+1    ; VBASE MSB
         STA   IBASE+1
         LDA   #0
         STA   VBASE1     ; VBASE1 LSB
         STA   IBASE1
                          ;
                          ; SAVE VGP POSITION ON THE STACK
                          ; AND SET TXPAGE TO MSB OF X
                          ;
         LDY   #0
DREADY:  LDA   (VBASE),Y  ; WAIT UNTIL VGP READY
         AND   #4
         BEQ   DREADY
         LDY   #11        ; SAVE POSITION
         LDX   #3
SAVLOP:  LDA   (VBASE),Y
         PHA
         DEY
         DEX
         BPL   SAVLOP
         AND   #2         ; SAVE PAGE NUMBER
         STA   TXPAGE     ; (MSB OF X POSITION)
                          ;
                          ; SET VGP Y POSITION ACCORDING TO
                          ; INTERLACED AND FORMAT PARAMETERS
                          ; UK INT - 512
                          ; UK NON - 256
                          ; US INT - 416
                          ; US NON - 208
                          ;
         LDY   #FORMO     ; GET FORMAT
         LDA   (JUMP2),Y
         TAX
         LDY   #INTRO     ; GET INTERLACED
         LDA   (JUMP2),Y
         BEQ   NONINT
         LDA   #2
         DEX
         BEQ   STOREY     
         LDX   #160
UKNON:   LDA   #1
         BNE   STOREY
NONINT:  DEX
         BEQ   UKNON
         LDX   #208
STOREY:  LDY   #10
         STA   (VBASE),Y
         INY
         TXA
         STA   (VBASE),Y
                          ;
                          ; NOW SET PRINTER LINEFEED STEP TO
                          ; 8/72" (HEIGHT OF 8 NEEDLES)
                          ;
         LDA   #ESCAPE
         JSR   JUMP1
         LDA   #$41       ; 'A
         JSR   JUMP1
         LDA   #8         ; FOR 8/72"
         JSR   JUMP1
         LDY   #PTYPEO
         LDA   (JUMP2),Y
         CMP   #3         ; MX80/MX100 ?
         BCS   DUMPLP     
         LDA   #ESCAPE
         JSR   JUMP1
         LDA   #$33       ; IF MX80 SEND SET LF SPACE COMMAND
         JSR   JUMP1
                          ;
DUMPLP:  LDY   #11
         LDA   (VBASE),Y  ; SAVE Y POSITION
         PHA
         DEY
         LDA   (VBASE),Y
         PHA
         DEY
         LDA   #0         ; RESET X POSITION
         STA   (VBASE),Y
         DEY
         LDA   TXPAGE     
         STA   (VBASE),Y
                          ;
         LDA   #ESCAPE    ; SET UP PRINTER
         JSR   JUMP1      ; TO ACCEPT GRAPHICS LINE
         LDY   #PTYPEO
         LDA   (JUMP2),Y  ; GET PRINTER TYPE
         CMP   #6
         BEQ   GFX80
         TAY
         LDA   #$4B       ; 'K
         DEY
         BEQ   GMX80      
         DEY
         DEY
         BNE   FULSCR     
GMX80:   JSR   JUMP1      ; 'K
         LDA   #$E0
         JSR   JUMP1      ; THEN 480 DOTS
         LDA   #1
         BNE   GLAST
                          ;
DUMPB2:  BNE   DUMPLP
                          ;
GFX80:   LDA   #$2A       ; '*
         JSR   JUMP1
         LDA   #5
FULSCR:  JSR   JUMP1
         LDA   #0         ; 512 DOTS
         JSR   JUMP1
         LDA   #2
GLAST:   JSR   JUMP1
                          ;
         LDA   #$80
         STA   XMASK      ; SET UP COLOUR BIT MASK
                          ;
LINELP:  ASL   XMASK      ; SHIFT XMASK
         BCC   XLIN1
         ROL   XMASK
XLIN1:   LDY   #11        ; SET Y POSITION
         PLA
         TAX
         PLA
         PHA
         STA   (VBASE),Y
         DEY
         TXA
         PHA
         STA   (VBASE),Y
         LDX   #8         ; 8 DOTS VERTICAL
GETDOT:  LDY   #11
         LDA   (VBASE),Y
         SEC
         SBC   #1
         STA   (VBASE),Y
         DEY
         LDA   (VBASE),Y
         SBC   #0
         STA   (VBASE),Y
         LDA   #15
         LDY   #0
         STA   (VBASE),Y  ; READ PIXEL COLOUR
GREADY:  LDA   (VBASE),Y
         AND   #4         ; WAIT UNTIL DONE
         BEQ   GREADY
         LDY   #4         ; READ COLOUR REGISTER
         LDA   (VBASE1),Y
         AND   XMASK      ; MASK OFF UNWANTED BITS
         BEQ   COLON
         LDY   #COLRO     ; COLOUR VGP ?
         LDA   (JUMP2),Y
         BEQ   COLOFF
         LDY   #$10       ; IF YES , READ OTHER PLANES
         LDA   (VBASE),Y
         AND   XMASK
         BEQ   COLON
         INY
         AND   (VBASE),Y
         BNE   COLOFF
COLON:   SEC   
         ROL   DOTS
         SEC   
         BCS   COLEX
                          ;
LINEB1:  SEC   
         BCS   LINELP
                          ;
DUMPB1:  BNE   DUMPB2
                          ;
COLOFF:  ASL   DOTS
         CLC
COLEX:   LDY   #INTRO
         LDA   (JUMP2),Y  ; INTERLACED ?
         BNE   COLINT
         ROL   DOTS
         DEX
COLINT:  DEX   
         BNE   GETDOT
                          ;
         LDA   DOTS       ; GET OUTPUT PATTERN
         JSR   JUMP1      ; AND SEND TO PRINTER
         LDY   #PTYPEO
         LDA   (JUMP2),Y
         TAX              ; SAVE PRINTER TYPE FOR LATER
         LDY   #9
         LDA   (VBASE),Y  ; INCREMENT X POSITION
         CLC
         ADC   #1
         STA   (VBASE),Y
         DEY
         LDA   (VBASE),Y
         ADC   #0
         STA   (VBASE),Y
         DEX
         BEQ   BND1E0     ; IF MX80
         DEX
         DEX
         BNE   BND200
BND1E0:  AND   #1         ; IF MX80 THEN STOP AT 1E0
         BEQ   LINEB1     
         INY
         LDA   (VBASE),Y
         CMP   #$E0
         BNE   LINEB1     
         BEQ   XLINE
                          ;
BND200:  EOR   TXPAGE     
         AND   #2
         BEQ   LINEB1     
                          ;
XLINE:   PLA
         PLA              ; DISCARD SAVED Y POSITION
         LDA   #10        ; OUTPUT LF CODE
         JSR   JUMP1
TSTKEY:  LDA   KBD
         BPL   TESTY
         LDY   CKBDS      ; RESET KEY STROBE
         CMP   #$84       ; CTRL D TYPED ?
         BEQ   RESET
TESTY:   LDY   #11
         LDA   (VBASE),Y
         DEY
         ORA   (VBASE),Y  ; IS Y POSITION = 0 ?
         BNE   DUMPB1     ; EVENTUALLY DUMPLP 
RESET:   LDA   #ESCAPE    ; RESET PRINTER LINE SPACE
         JSR   JUMP1
         LDY   #PTYPEO    
         LDA   (JUMP2),Y  ; GET PRINTER TYPE 
         LDX   #$32
         CMP   #3         ; MX80/MX100 ? 
         BCS   NMXRST
         INX              ; OUTPUT '3 IF SO
NMXRST:  TXA
         JSR   JUMP1
         LDX   #3
         LDY   #8         
RESPOS:  PLA
         STA   (VBASE),Y
         INY
         DEX
         BPL   RESPOS
         RTS
                          ;